home *** CD-ROM | disk | FTP | other *** search
/ PC-X 1997 October / pcx14_9710.iso / swag / math.swg / 0128_Complex Number Component.pas < prev    next >
Encoding:
Pascal/Delphi Source File  |  1997-08-30  |  35.6 KB  |  1,142 lines
  1. {$N+,E+} {Use math coprocessor, if any, emulate otherwise.}
  2. UNIT ComplexOps;  { see demo at end }
  3.  
  4.  {This UNIT provides complex arithmetic and transcendental functions.
  5.  
  6.   (C) Copyright 1990, 1992, Earl F. Glynn, Overland Park, KS.  Compuserve 73257,3527.
  7.   All rights reserved.  This program may be freely distributed only for
  8.   non-commercial use.
  9.  
  10.   Some ideas in this UNIT were borrowed from "A Pascal Tool for Complex
  11.   Numbers", Journal of Pascal, Ada, & Modula-2, May/June 1985, pp. 23-29.
  12.   Many complex formulas were taken from Chapter 4, "Handbook of Mathematical
  13.   Functions" (Ninth Printing), Abramowitz and Stegun (editors), Dover, 1972.}
  14.  
  15. INTERFACE
  16.  
  17.   TYPE
  18.     RealType    = DOUBLE;
  19.     ComplexForm = (polar,rectangular);
  20.     Complex =
  21.       RECORD
  22.         CASE form:  ComplexForm OF
  23.           rectangular:  (x,y    :  RealType);  {z = x + y*i}
  24.           polar      :  (r,theta:  RealType);  {z = r*CIS(theta)}
  25.       END;                 {where CIS(theta) = COS(theta) + SIN(theta)*i}
  26.                            {      theta = -PI..PI (in canonical form)}
  27.  
  28.   CONST
  29.     MaxTerm    : BYTE     = 35;
  30.     EpsilonSqr : RealType = 1.0E-20;
  31.     Infinity   : RealType = 1.0E25;    {virtual infinity}
  32.  
  33.                              {complex number definition/conversion/output}
  34.   PROCEDURE CConvert (VAR z:  Complex; f:  ComplexForm);
  35.   PROCEDURE CSet (VAR z:  Complex; a,b:  RealType; f:  ComplexForm);
  36.   FUNCTION  CStr (z:  Complex; w,d:  BYTE; f:  ComplexForm):  STRING;
  37.  
  38.                              {complex arithmetic}
  39.   PROCEDURE CAdd  (VAR z:  Complex; a,b:  Complex);    {z = a + b}
  40.   PROCEDURE CDiv  (VAR z:  Complex; a,b:  Complex);    {z = a / b}
  41.   PROCEDURE CMult (VAR z:  Complex; a,b:  Complex);    {z = a * b}
  42.   PROCEDURE CSub  (VAR z:  Complex; a,b:  Complex);    {z = a - b}
  43.   PROCEDURE CNeg  (VAR z:  Complex; a  :  Complex);    {z = -a   }
  44.  
  45.                              {complex natural log, exponential}
  46.   PROCEDURE CLn   (VAR fn :  Complex; z:  Complex);   {fn  = ln(z) }
  47.   PROCEDURE CExp  (VAR z  :  Complex; a:  Complex);   {z   = exp(a)}
  48.   PROCEDURE CPwr  (VAR z  :  Complex; a,b:  Complex); {z   = a^b   }
  49.  
  50.                              {complex trig functions}
  51.   PROCEDURE CCos  (VAR z:  Complex; a:  Complex);     {z   = cos(a)}
  52.   PROCEDURE CSin  (VAR z:  Complex; a:  Complex);     {z   = sin(a)}
  53.   PROCEDURE CTan  (VAR z:  Complex; a:  Complex);     {z   = tan(a)}
  54.  
  55.   PROCEDURE CSec  (VAR z:  Complex; a:  Complex);     {z   = sec(a)}
  56.   PROCEDURE CCsc  (VAR z:  Complex; a:  Complex);     {z   = csc(a)}
  57.   PROCEDURE CCot  (VAR z:  Complex; a:  Complex);     {z   = cot(a)}
  58.  
  59.                              {complex hyperbolic functions}
  60.   PROCEDURE CCosh (VAR z:  Complex; a:  Complex);     {z   = cosh(a)}
  61.   PROCEDURE CSinh (VAR z:  Complex; a:  Complex);     {z   = sinh(a)}
  62.   PROCEDURE CTanh (VAR z:  Complex; a:  Complex);     {z   = tanh(a)}
  63.  
  64.   PROCEDURE CSech (VAR z:  Complex; a:  Complex);     {z   = sech(a)}
  65.   PROCEDURE CCsch (VAR z:  Complex; a:  Complex);     {z   = csch(a)}
  66.   PROCEDURE CCoth (VAR z:  Complex; a:  Complex);     {z   = coth(a)}
  67.  
  68.                              {miscellaneous complex functions}
  69.   FUNCTION  CAbs (z:  Complex):  RealType;                 {CAbs = |z|}
  70.   FUNCTION  CAbsSqr (z:  Complex):  RealType;           {CAbsSqr = |z|^2}
  71.   PROCEDURE CIntPwr (VAR z:  Complex; a:  Complex; n:  INTEGER); {z = a^n}
  72.   PROCEDURE CRealPwr (VAR z:  Complex; a:  Complex; x:  RealType); {z = a^x}
  73.   PROCEDURE CConjugate (VAR z:  Complex; a:  Complex);        {z = a*}
  74.   PROCEDURE CSqrt (VAR z:  Complex; a:  Complex);      {z = SQRT(a)}
  75.   PROCEDURE CRoot (VAR z:  Complex; a:  Complex; k,n:  WORD); {z = a^(1/n)}
  76.  
  77.                              {complex Bessel functions of order zero}
  78.   PROCEDURE CI0   (VAR sum:  Complex; z:  Complex);  {sum = I0(z)}
  79.   PROCEDURE CJ0   (VAR sum:  Complex; z:  Complex);  {sum = J0(z)}
  80.  
  81.   PROCEDURE CLnGamma (VAR z:  Complex; a:  Complex);
  82.   PROCEDURE CGamma   (VAR z:  Complex; a:  Complex);
  83.  
  84.                                   {treat "fuzz" of real numbers}
  85.   PROCEDURE CDeFuzz (VAR z:  Complex);
  86.   FUNCTION  DeFuzz (x:  RealType):  RealType;
  87.   PROCEDURE SetFuzz (value:  RealType);
  88.  
  89.                                   {miscellaneous}
  90.   FUNCTION FixAngle (theta:  RealType):  RealType;    {-PI < theta <= PI}
  91.   FUNCTION Pwr (x,y:  RealType):  RealType;    {Pwr = x^y}
  92.   FUNCTION Log10 (x:  RealType):  RealType;
  93.   FUNCTION LongMod (l1,l2:  LongInt):  LongInt;
  94.   FUNCTION Cosh (x:  RealType):  RealType;
  95.   FUNCTION Sinh (x:  RealType):  RealType;
  96.  
  97. IMPLEMENTATION
  98.  
  99.   VAR
  100.     fuzz     :  RealType;
  101.     Cone     :  Complex;
  102.     Cinfinity:  Complex;
  103.     Czero    :  Complex;
  104.     hLnPI    :  RealType;
  105.     hLn2PI   :  RealType;
  106.     ln2      :  RealType;
  107.  
  108.                              {complex number definition/conversion/output}
  109.   PROCEDURE CConvert (VAR z:  Complex; f:  ComplexForm);
  110.     VAR a:  Complex;
  111.   BEGIN
  112.     IF   z.form = f
  113.     THEN CDeFuzz (z)
  114.     ELSE BEGIN
  115.       CASE z.form OF
  116.         polar:            {polar-to-rectangular conversion}
  117.           BEGIN
  118.             a.form := rectangular;
  119.             a.x := z.r * COS(z.theta);
  120.             a.y := z.r * SIN(z.theta)
  121.           END;
  122.         rectangular:      {rectangular-to-polar conversion}
  123.           BEGIN
  124.             a.form := polar;
  125.             IF   DeFuzz(z.x) = 0.0
  126.             THEN BEGIN
  127.               IF   DeFuzz(z.y) = 0.0
  128.               THEN BEGIN
  129.                 a.r     := 0.0;
  130.                 a.theta := 0.0
  131.               END
  132.               ELSE
  133.                 IF   z.y > 0.0
  134.                 THEN BEGIN
  135.                   a.r := z.y;
  136.                   a.theta := 0.5*PI
  137.                 END
  138.                 ELSE BEGIN
  139.                   a.r := -z.y;
  140.                   a.theta := -0.5*PI
  141.                 END
  142.             END
  143.             ELSE BEGIN
  144.               a.r := CAbs(z);
  145.               a.theta := ARCTAN(z.y/z.x);   {4th/1st quadrant -PI/2..PI/2}
  146.               IF   z.x < 0.0                {2nd/3rd quadrants}
  147.               THEN
  148.                 IF   z.y >= 0.0
  149.                 THEN a.theta :=  PI + a.theta {2nd quadrant:  PI/2..PI}
  150.                 ELSE a.theta := -PI + a.theta {3rd quadrant: -PI..-PI/2}
  151.             END
  152.           END;
  153.       END;
  154.       CDeFuzz (a);
  155.       z := a
  156.     END
  157.   END {CConvert};
  158.  
  159.   PROCEDURE CSet (VAR z:  Complex; a,b:  RealType; f:  ComplexForm);
  160.   BEGIN
  161.     z.form := f;
  162.     CASE f OF
  163.       polar:
  164.         BEGIN
  165.           z.r := a;
  166.           z.theta := b
  167.         END;
  168.       rectangular:
  169.         BEGIN
  170.           z.x := a;
  171.           z.y := b
  172.         END;
  173.     END
  174.   END {CSet};
  175.  
  176.   FUNCTION  CStr (z:  Complex; w,d:  BYTE; f:  ComplexForm):  STRING;
  177.     VAR s1,s2:  STRING;
  178.   BEGIN
  179.     CConvert (z,f);
  180.     CASE f OF
  181.       polar:
  182.         BEGIN
  183.           Str (z.r:w:d, s1);
  184.           Str (z.theta:w:d, s2);
  185.           CStr := s1+'*CIS('+s2+')'
  186.         END;
  187.       rectangular:
  188.         BEGIN
  189.           Str (z.x:w:d, s1);
  190.           Str (ABS(z.y):w:d, s2);
  191.           IF   z.y >= 0
  192.           THEN CStr := s1+' +'+s2+'i'
  193.           ELSE CStr := s1+' -'+s2+'i'
  194.         END
  195.     END
  196.   END {CStr};
  197.  
  198.                                   {complex arithmetic}
  199.   PROCEDURE CAdd  (VAR z:  Complex; a,b:  Complex);    {z = a + b}
  200.   BEGIN                                               {complex addition}
  201.     CConvert (a,rectangular);
  202.     CConvert (b,rectangular);
  203.     z.form := rectangular;
  204.     z.x := a.x + b.x;   {real part}
  205.     z.y := a.y + b.y;   {imaginary part}
  206.   END {CAdd};
  207.  
  208.   PROCEDURE CDiv  (VAR z:  Complex; a,b:  Complex);    {z = a / b}
  209.     VAR temp:  RealType;
  210.   BEGIN
  211.     CConvert (b,a.form);    {arbitrarily convert one to type of other}
  212.     z.form := a.form;
  213.     CASE a.form OF
  214.       polar:
  215.         BEGIN
  216.           z.r := a.r / b.r;
  217.           z.theta := FixAngle(a.theta - b.theta)
  218.         END;
  219.       rectangular:
  220.         BEGIN
  221.           temp := SQR(b.x) + SQR(b.y);
  222.           z.x := (a.x*b.x + a.y*b.y) / temp;
  223.           z.y := (a.y*b.x - a.x*b.y) / temp
  224.         END
  225.     END
  226.   END {CDiv};
  227.  
  228.   PROCEDURE CMult (VAR z:  Complex; a,b:  Complex);    {z = a * b}
  229.   BEGIN
  230.     CConvert (b,a.form);    {arbitrarily convert one to type of other}
  231.     z.form := a.form;
  232.     CASE a.form OF
  233.       polar:
  234.         BEGIN
  235.           z.r := a.r * b.r;
  236.           z.theta := FixAngle(a.theta + b.theta)
  237.         END;
  238.       rectangular:
  239.         BEGIN
  240.           z.x := a.x*b.x - a.y*b.y;
  241.           z.y := a.x*b.y + a.y*b.x
  242.         END
  243.     END
  244.   END {CMult};
  245.  
  246.   PROCEDURE CSub  (VAR z:  Complex; a,b:  Complex);    {z = a - b}
  247.   BEGIN                                               {complex subtraction}
  248.     CConvert (a,rectangular);
  249.     CConvert (b,rectangular);
  250.     z.form := rectangular;
  251.     z.x := a.x - b.x;   {real part}
  252.     z.y := a.y - b.y;   {imaginary part}
  253.   END {CSub};
  254.  
  255.   PROCEDURE CNeg  (VAR z:  Complex; a  :  Complex);    {z = -a   }
  256.   BEGIN
  257.     z.form := a.form;
  258.     CASE a.form OF
  259.       polar:
  260.         BEGIN
  261.           z.r := a.r;
  262.           z.theta := FixAngle(a.theta + PI)
  263.         END;
  264.       rectangular:
  265.         BEGIN
  266.           z.x := -a.x;
  267.           z.y := -a.y
  268.         END
  269.     END
  270.   END {CNeg};
  271.                                   {complex natural log, exponential}
  272.   PROCEDURE CLn (VAR fn:  Complex; z:  Complex);  {fn  = ln(z)}
  273.   BEGIN  {Abramowitz formula 4.1.2 on p. 67}
  274.     CConvert (z,polar);
  275.     fn.form := rectangular;
  276.     fn.x := LN(z.r);
  277.     fn.y := FixAngle(z.theta)
  278.   END {CLn};  {principal value only}
  279.  
  280.   PROCEDURE CExp  (VAR z  :  Complex; a:  Complex);   {z   = exp(a)}
  281.     VAR
  282.       temp:  RealType;
  283.   BEGIN  {Euler's Formula:  Abramowitz formula 4.3.47 on p. 74}
  284.     CConvert (a,rectangular);
  285.     temp := EXP(a.x);
  286.     CSet (z, temp*COS(a.y),temp*SIN(a.y), rectangular)
  287.   END {CExp};
  288.  
  289.   PROCEDURE CPwr  (VAR z  :  Complex; a,b:  Complex); {z   = a^b   }
  290.     VAR
  291.       blna,lna:  Complex;
  292.   BEGIN  {Abramowitz formula 4.2.7 on p. 69}
  293.     CDeFuzz (a);
  294.     CDeFuzz (b);
  295.     IF   CAbsSqr(a) = 0.0
  296.     THEN
  297.       IF    (CAbsSqr(b) = 0.0)
  298.       THEN  z := Cone                   {lim a^a = 1 as a -> 0}
  299.       ELSE  z := Czero                  {0^b = 0, b <> 0}
  300.     ELSE BEGIN
  301.       CLn (lna,a);
  302.       CMult (blna,b,lna);
  303.       CExp (z, blna)
  304.     END
  305.   END {CPwr};
  306.                                   {complex trig functions}
  307.   PROCEDURE CCos  (VAR z:  Complex; a:  Complex);     {z   = cos(a)}
  308.   BEGIN  {Abramowitz formula 4.3.56 on p. 74}
  309.     CConvert (a,rectangular);
  310.     CSet (z, COS(a.x)*COSH(a.y), -SIN(a.x)*SINH(a.y), rectangular)
  311.   END {CCos};
  312.  
  313.   PROCEDURE CSin  (VAR z:  Complex; a:  Complex);     {z   = sin(a)}
  314.   BEGIN  {Abramowitz formula 4.3.55 on p. 74}
  315.     CConvert (a,rectangular);
  316.     CSet (z, SIN(a.x)*COSH(a.y), COS(a.x)*SINH(a.y), rectangular)
  317.   END {CSin};
  318.  
  319.   PROCEDURE CTan  (VAR z:  Complex; a:  Complex);     {z   = tan(a)}
  320.     VAR
  321.       temp:  RealType;
  322.   BEGIN  {Abramowitz formula 4.3.57 on p. 74}
  323.     CConvert (a,rectangular);
  324.     temp := COS(2.0*a.x) + COSH(2.0*a.y);
  325.     IF   DeFuzz(temp) <> 0.0
  326.     THEN BEGIN
  327.       CSet (z,SIN(2.0*a.x)/temp,SINH(2.0*a.y)/temp,rectangular)
  328.     END
  329.     ELSE z := Cinfinity
  330.   END {CTan};
  331.  
  332.   PROCEDURE CSec  (VAR z:  Complex; a:  Complex);     {z   = sec(a)}
  333.     VAR
  334.       temp:  Complex;
  335.   BEGIN  {Abramowitz formula 4.3.5 on p. 72}
  336.     CCos (temp, a);
  337.     IF   DeFuzz( Cabs(temp) ) <> 0.0
  338.     THEN CDiv (z, Cone,temp)
  339.     ELSE z := Cinfinity
  340.   END {CSec};
  341.  
  342.   PROCEDURE CCsc  (VAR z:  Complex; a:  Complex);     {z   = csc(a)}
  343.     VAR
  344.       temp:  Complex;
  345.   BEGIN  {Abramowitz formula 4.3.4 on p. 72}
  346.     CSin (temp, a);
  347.     IF   DeFuzz( Cabs(temp) ) <> 0.0
  348.     THEN CDiv (z, Cone,temp)
  349.     ELSE z := Cinfinity
  350.   END {CCsc};
  351.  
  352.   PROCEDURE CCot  (VAR z:  Complex; a:  Complex);     {z   = cot(a)}
  353.     VAR
  354.       temp:  RealType;
  355.   BEGIN  {Abramowitz formula 4.3.58 on p. 74}
  356.     CConvert (a,rectangular);
  357.     temp := COSH(2.0*a.y) - COS(2.0*a.x);
  358.     IF   DeFuzz(temp) <> 0.0
  359.     THEN BEGIN
  360.       CSet (z,SIN(2.0*a.x)/temp,-SINH(2.0*a.y)/temp,rectangular)
  361.     END
  362.     ELSE z := Cinfinity
  363.   END {CCot};
  364.  
  365.                                   {complex hyperbolic functions}
  366.   PROCEDURE CCosh (VAR z:  Complex; a:  Complex);     {z   = cosh(a)}
  367.   BEGIN  {Abramowitz formula 4.5.50 on p. 84}
  368.     CConvert (a,rectangular);
  369.     CSet (z, COSH(a.x)*COS(a.y), SINH(a.x)*SIN(a.y), rectangular)
  370.   END {CCosh};
  371.  
  372.   PROCEDURE CSinh (VAR z:  Complex; a:  Complex);     {z   = sinh(a)}
  373.   BEGIN  {Abramowitz formula 4.5.49 on p.84}
  374.     CConvert (a,rectangular);
  375.     CSet (z, SINH(a.x)*COS(a.y), COSH(a.x)*SIN(a.y), rectangular)
  376.   END {CSinh};
  377.  
  378.   PROCEDURE CTanh (VAR z:  Complex; a:  Complex);     {z   = tanh(a)}
  379.     VAR
  380.       temp:  RealType;
  381.   BEGIN  {Abramowitz formula 4.5.51 on p. 84}
  382.     CConvert (a,rectangular);
  383.     temp := COSH(2.0*a.x) + COS(2.0*a.y);
  384.     IF   DeFuzz(temp) <> 0.0
  385.     THEN BEGIN
  386.       CSet (z,SINH(2.0*a.x)/temp,SIN(2.0*a.y)/temp,rectangular)
  387.     END
  388.     ELSE z := Cinfinity
  389.   END {CTanh};
  390.  
  391.   PROCEDURE CSech (VAR z:  Complex; a:  Complex);     {z   = sech(a)}
  392.     VAR
  393.       temp:  Complex;
  394.   BEGIN  {Abramowitz formula 4.5.5 on p. 83}
  395.     CCosh (temp, a);
  396.     IF   DeFuzz( Cabs(temp) ) <> 0.0
  397.     THEN CDiv (z, Cone,temp)
  398.     ELSE z := Cinfinity
  399.   END {CSec};
  400.  
  401.   PROCEDURE CCsch (VAR z:  Complex; a:  Complex);     {z   = csch(a)}
  402.     VAR
  403.       temp:  Complex;
  404.   BEGIN  {Abramowitz formula 4.5.4 on p. 83}
  405.     CSinh (temp, a);
  406.     IF   DeFuzz( Cabs(temp) ) <> 0.0
  407.     THEN CDiv (z, Cone,temp)
  408.     ELSE z := Cinfinity
  409.   END {CCsch};
  410.  
  411.   PROCEDURE CCoth (VAR z:  Complex; a:  Complex);     {z   = coth(a)}
  412.     VAR
  413.       temp:  RealType;
  414.   BEGIN  {Abramowitz formula 4.5.52 on p. 84}
  415.     CConvert (a,rectangular);
  416.     temp := COSH(2.0*a.x) - COS(2.0*a.y);
  417.     IF   DeFuzz(temp) <> 0.0
  418.     THEN BEGIN
  419.       CSet (z,SINH(2.0*a.x)/temp,-SIN(2.0*a.y)/temp,rectangular)
  420.     END
  421.     ELSE z := Cinfinity
  422.   END {CCoth};
  423.  
  424.                                   {miscellaneous complex functions}
  425.   FUNCTION CAbs (z:  Complex):  RealType;                  {CAbs = |z|}
  426.   BEGIN
  427.     CASE z.form OF
  428.       rectangular:  CAbs := SQRT( SQR(z.x) + SQR(z.y) );
  429.       polar:        CAbs := z.r
  430.     END
  431.   END {CAbs};
  432.  
  433.   FUNCTION CAbsSqr (z:  Complex):  RealType;            {CAbsSqr = |z|^2}
  434.   BEGIN
  435.     CASE z.form OF
  436.       rectangular:  CAbsSqr := SQR(z.x) + SQR(z.y);
  437.       polar:        CAbsSqr := SQR(z.r)
  438.     END
  439.   END {CAbsSqr};
  440.  
  441.   PROCEDURE CIntPwr (VAR z:  Complex; a:  Complex; n:  INTEGER); {z = a^n}
  442.     {CIntPwr directly applies DeMoivre's theorem to calculate
  443.      an integer power of a complex number.  The formula holds
  444.      for both positive and negative values of 'n'.}
  445.   BEGIN
  446.     IF   CAbsSqr(a) = 0.0
  447.     THEN
  448.       IF    n = 0
  449.       THEN  z := Cone                   {lim a^a = 1 as a -> 0}
  450.       ELSE  z := Czero                  {0^n = 0, except for 0^0=1}
  451.     ELSE BEGIN
  452.       CConvert (a,polar);
  453.       z.form := polar;
  454.       z.r := Pwr(a.r,n);
  455.       z.theta := FixAngle(n*a.theta)
  456.     END
  457.   END {CIntPwr};
  458.  
  459.   PROCEDURE CRealPwr (VAR z:  Complex; a:  Complex; x:  RealType); {z = a^x}
  460.   BEGIN
  461.     IF   CAbsSqr(a) = 0.0
  462.     THEN
  463.       IF    Defuzz(x) = 0.0
  464.       THEN  z := Cone                   {lim a^a = 1 as a -> 0}
  465.       ELSE  z := Czero                  {0^n = 0, except for 0^0=1}
  466.     ELSE BEGIN
  467.       CConvert (a,polar);
  468.       z.form := polar;
  469.       z.r := Pwr(a.r,x);
  470.       z.theta := FixAngle(x*a.theta)
  471.     END
  472.   END {CRealPwr};
  473.  
  474.   PROCEDURE CConjugate (VAR z:  Complex; a:  Complex);      {z = a*}
  475.   BEGIN
  476.     z.form := a.form;
  477.     CASE a.form OF
  478.       polar:
  479.         BEGIN
  480.           z.r := a.r;
  481.           z.theta := FixAngle(-a.theta)
  482.         END;
  483.       rectangular:
  484.         BEGIN
  485.           z.x := a.x;
  486.           z.y := -a.y
  487.         END
  488.     END
  489.   END {CConjugate};
  490.  
  491.   PROCEDURE CSqrt (VAR z:  Complex; a:  Complex);      {z = SQRT(a)}
  492.   BEGIN
  493.     CRoot (z, a, 0,2)  {return only one of the two values}
  494.   END {CSqrt};
  495.                                            {z = a^(1/n), n > 0}
  496.   PROCEDURE CRoot (VAR z:  Complex; a:  Complex; k,n:  WORD);
  497.     {CRoot can calculate all 'n' roots of 'a' by varying 'k' from 0..n-1.}
  498.     {This is another application of DeMoivre's theorem.  See CIntPwr.}
  499.   BEGIN
  500.     IF   CAbs(a) = 0.0
  501.     THEN z := Czero                   {0^z = 0, except 0^0 is undefined}
  502.     ELSE BEGIN
  503.       CConvert (a,polar);
  504.       z.form := polar;
  505.       z.r := Pwr(a.r,1.0/n);
  506.       z.theta := FixAngle((a.theta + k*2.0*PI)/n)
  507.     END
  508.   END {CRoot};
  509.  
  510.                              {complex Bessel functions of order zero}
  511.   PROCEDURE CI0   (VAR sum:  Complex; z:  Complex);  {sum = I0(z)}
  512.     {I0(z) = Σ ( (¼z^2)^k / (k!)^2 ), k=0,1,2,...,∞}
  513.     VAR
  514.       i      :  BYTE;
  515.       SizeSqr:  RealType;
  516.       term   :  Complex;
  517.       zSQR25 :  Complex;
  518.   BEGIN
  519.     CConvert (z,rectangular);
  520.     sum := Cone;                       {term 0}
  521.     Cmult (zSQR25, z,z);
  522.     zSQR25.x := 0.25 * zSQR25.x;
  523.     zSQR25.y := 0.25 * zSQR25.y;       {¼z^2}
  524.     term := zSQR25;
  525.     CAdd (sum, sum,zSQR25);            {term 1}
  526.     i := 1;
  527.     REPEAT
  528.       CMult (term,zSQR25,term);
  529.       INC (i);
  530.       term.x := term.x / SQR(i);
  531.       term.y := term.y / SQR(i);
  532.       CAdd (sum, sum,term);       {sum := sum + term}
  533.       SizeSqr := SQR(term.x) + SQR(term.y)
  534.     UNTIL (i > MaxTerm) OR (SizeSqr < EpsilonSqr)
  535.   END {CI0};
  536.  
  537.   PROCEDURE CJ0   (VAR sum:  Complex; z:  Complex);  {sum = J0(z)}
  538.     {J0(z) = Σ ( (-1)^k * (¼z^2)^k / (k!)^2 ), k=0,1,2,...,∞}
  539.     VAR
  540.       addflag:  BOOLEAN;
  541.       i      :  BYTE;
  542.       SizeSqr:  RealType;
  543.       term   :  Complex;
  544.       zSQR25 :  Complex;
  545.   BEGIN
  546.     CConvert (z,rectangular);
  547.     sum := Cone;                       {term 0}
  548.     Cmult (zSQR25, z,z);
  549.     zSQR25.x := 0.25 * zSQR25.x;
  550.     zSQR25.y := 0.25 * zSQR25.y;       {¼z^2}
  551.     term := zSQR25;
  552.     CSub (sum, sum,zSQR25);            {term 1}
  553.     addflag := FALSE;
  554.     i := 1;
  555.     REPEAT
  556.       CMult (term,zSQR25,term);
  557.       INC (i);
  558.       addflag := NOT addflag;
  559.       term.x := term.x / SQR(i);
  560.       term.y := term.y / SQR(i);
  561.       IF   addflag
  562.       THEN CAdd (sum, sum,term)        {sum := sum + term}
  563.       ELSE CSub (sum, sum,term);       {sum := sum - term}
  564.       SizeSqr := SQR(term.x) + SQR(term.y)
  565.     UNTIL (i > MaxTerm) OR (SizeSqr < EpsilonSqr)
  566.   END {CJ0};
  567.  
  568.   PROCEDURE CApproxLnGamma (VAR sum:  Complex; z:  Complex);
  569.     {This is the approximation used in the National Bureau of
  570.      Standards "Table of the Gamma Function for Complex Arguments,"
  571.      Applied Mathematics Series 34, 1954.  The NBS table was created
  572.      using this approximation over the area  9 ≤ Re(z) ≤ 10 and
  573.      0 ≤ Im(z) ≤ 10.  Other table values were computed using the
  574.      relationship ln Γ(z+1) = ln z + ln Γ(z).}
  575.     CONST
  576.       c:  ARRAY[1..8] OF RealType
  577.        =  (1/12, -1/360, 1/1260, -1/1680, 1/1188, -691/360360,
  578.            1/156, -3617/122400);
  579.     VAR
  580.       i     :  WORD;
  581.       powers:  ARRAY[1..8] OF Complex;
  582.       temp1 :  Complex;
  583.       temp2 :  Complex;
  584.   BEGIN
  585.     CConvert (z,rectangular);
  586.     CLn  (temp1,z);                              {ln(z}
  587.     CSet (temp2, z.x-0.5, z.y, rectangular);     {z - 0.5}
  588.     CMult (sum, temp1,temp2);                    {(z - 0.5)*ln(z)}
  589.     CSub (sum, sum,z);                           {(z - 0.5)*ln(z) - z}
  590.     sum.x := sum.x + hLn2PI;
  591.  
  592.     temp1 := Cone;
  593.     CDiv (powers[1], temp1, z);                  {z^-1}
  594.     CMult (temp2, powers[1],powers[1]);          {z^-2}
  595.     FOR i := 2 TO 8 DO
  596.       CMult (powers[i], powers[i-1],temp2);
  597.     FOR i := 8 DOWNTO 1 DO BEGIN
  598.       CSet (temp1, c[i]*powers[i].x, c[i]*powers[i].y, rectangular);
  599.       CAdd (sum, sum,temp1);
  600.     END
  601.   END {CApproxLnGamma};
  602.  
  603.   PROCEDURE CLnGamma (VAR z:  Complex; a:  Complex);
  604.     VAR
  605.       lna :  Complex;
  606.       temp:  Complex;
  607.   BEGIN
  608.     CConvert (a, rectangular);
  609.  
  610.     IF   (a.x <= 0.0) AND (DeFuzz(a.y) = 0.0)
  611.     THEN
  612.       IF   DeFuzz(INT(a.x-1E-8) - a.x) = 0.0     {negative integer?}
  613.       THEN BEGIN
  614.         z := Cinfinity;
  615.         EXIT
  616.       END;
  617.  
  618.     IF   a.y < 0.0                     {3rd or 4th quadrant?}
  619.     THEN BEGIN
  620.       CConjugate (a, a);
  621.       CLnGamma (z, a);                 {try again in 1st or 2nd quadrant}
  622.       CConjugate (z, z)                {left this out!  1/3/91}
  623.     END
  624.     ELSE BEGIN
  625.       IF   a.x < 9.0                   {"left" of NBS table range}
  626.       THEN BEGIN
  627.         CLn (lna, a);
  628.         CSet (a, a.x+1.0, a.y, rectangular);
  629.         CLnGamma (temp,a);
  630.         CSub (z, temp,lna)
  631.       END
  632.       ELSE CApproxLnGamma (z,a)  {NBS table range:  9 ≤ Re(z) ≤ 10}
  633.     END
  634.   END {CLnGamma};
  635.  
  636.   PROCEDURE CGamma (VAR z:  Complex; a:  Complex);
  637.     VAR
  638.       lnz:  Complex;
  639.   BEGIN
  640.     CLnGamma (lnz,a);
  641.     IF   lnz.x >= 75.0       {arbitrary cutoff for infinity}
  642.     THEN z := Cinfinity
  643.     ELSE
  644.       IF   lnz.x < -200.0
  645.       THEN z := Czero        {avoid underflow}
  646.       ELSE CExp (z, lnz);
  647.   END {CGamma};
  648.  
  649.                                   {treat "fuzz" of real numbers}
  650.   PROCEDURE CDeFuzz (VAR z:  Complex);
  651.   BEGIN
  652.     CASE z.form OF
  653.       rectangular:
  654.         BEGIN
  655.           z.x := DeFuzz(z.x);
  656.           z.y := DeFuzz(z.y);
  657.         END;
  658.       polar:
  659.         BEGIN
  660.           z.r := DeFuzz(z.r);
  661.           IF   z.r = 0.0
  662.           THEN z.theta := 0.0     {canonical form when radius is zero}
  663.           ELSE z.theta := DeFuzz(z.theta)
  664.         END
  665.     END
  666.   END {CDeFuzz};
  667.  
  668.   FUNCTION  DeFuzz (x:  RealType):  RealType;
  669.   BEGIN
  670.     IF   ABS(x) < fuzz
  671.     THEN Defuzz := 0
  672.     ELSE Defuzz := x
  673.   END {Defuzz};
  674.  
  675.   PROCEDURE SetFuzz (value:  RealType);
  676.   BEGIN
  677.     fuzz := value
  678.   END {SetFuzz};
  679.  
  680.                                   {miscellaneous}
  681.   FUNCTION FixAngle (theta:  RealType):  RealType;    {-PI < theta <= PI}
  682.   BEGIN
  683.     WHILE theta > PI DO
  684.       theta := theta - 2.0*PI;
  685.     WHILE theta <= -PI DO
  686.       theta := theta + 2.0*PI;
  687.     FixAngle := DeFuzz(theta)
  688.   END {FixAngle};
  689.  
  690.   FUNCTION Pwr (x,y:  RealType):  RealType;        {Pwr = x^y}
  691.   BEGIN
  692.     IF   DeFuzz(x) = 0.0
  693.     THEN
  694.       IF   DeFuzz(y) = 0.0
  695.       THEN Pwr := 1.0    {0^0 = 1 (i.e., lim x^x = 1 as x -> 0)}
  696.       ELSE Pwr := 0.0
  697.     ELSE Pwr := EXP( LN(x)*y )
  698.   END {Pwr};
  699.  
  700.   FUNCTION Log10 (x:  RealType):  RealType;
  701.   BEGIN
  702.     Log10 := LN(x) / LN(10)
  703.   END {Log10};
  704.  
  705.   FUNCTION LongMod (l1,l2:  LongInt):  LongInt;
  706.   BEGIN
  707.     LongMod := l1 - l2*(l1 DIV l2)
  708.   END {LongMod};
  709.  
  710.   FUNCTION Cosh (x:  RealType):  RealType;
  711.   BEGIN
  712.     Cosh := 0.5*( EXP(x) + EXP(-x) )
  713.   END {Cosh};
  714.  
  715.   FUNCTION Sinh (x:  RealType):  RealType;
  716.   BEGIN
  717.     Sinh := 0.5*( EXP(x) - EXP(-x) )
  718.   END {Sinh};
  719.  
  720. BEGIN
  721.   SetFuzz (1.0E-12);
  722.   CSet ( Cone, 1.0, 0.0, rectangular);
  723.   CSet (Czero, 0.0, 0.0, rectangular);
  724.   CSet (Cinfinity, Infinity, Infinity, rectangular);
  725.   hLnPI := 0.5*(LN(PI));
  726.   hLn2PI := 0.5*(LN(2.0*PI));
  727.   ln2 := LN(2.0)
  728. END.
  729.  
  730. {-------------  DEMO ----  CUT HERE ------ }
  731. {$N+,E+}
  732. PROGRAM cdemo;
  733.  
  734.  {This PROGRAM demonstrates the use of the ComplexOps UNIT.
  735.  
  736.   (C) Copyright 1990, 1992, Earl F. Glynn, Overland Park, KS.  Compuserve 73257,3527.
  737.   All rights reserved.  This program may be freely distributed only for
  738.   non-commercial use.}
  739.  
  740.  
  741.   USES ComplexOps;
  742.  
  743.   VAR
  744.     a      :  ARRAY[1..22] OF Complex;
  745.     csave  :  ARRAY[1..22] OF Complex;
  746.     k,m    :  WORD;
  747.     n      :  INTEGER;
  748.     x,y    :  RealType;
  749.     z,z1,z2:  Complex;
  750.  
  751. BEGIN
  752.  
  753.   WRITELN ('Demo ComplexOPs PROCEDUREs and FUNCTIONs');
  754.   WRITELN;
  755.   WRITELN ('  Notes:  1.  CIS(w) = COS(w) + i*SIN(w), w = -PI..PI');
  756.   WRITELN ('          2.  z = x + i*y');
  757.   WRITELN;
  758.   WRITELN;
  759.  
  760.   CSet (a[ 1],  0.0,  0.0, rectangular);
  761.   CSet (a[ 2],  0.5,  0.5, rectangular);
  762.   CSet (a[ 3], -0.5,  0.5, rectangular);
  763.   CSet (a[ 4], -0.5, -0.5, rectangular);
  764.   CSet (a[ 5],  0.5, -0.5, rectangular);
  765.   CSet (a[ 6],  1.0,  0.0, rectangular);
  766.   CSet (a[ 7],  1.0,  1.0, rectangular);
  767.   CSet (a[ 8],  0.0,  1.0, rectangular);
  768.   CSet (a[ 9], -1.0,  1.0, rectangular);
  769.   CSet (a[10], -1.0,  0.0, rectangular);
  770.   CSet (a[11], -1.0, -1.0, rectangular);
  771.   CSet (a[12],  0.0, -1.0, rectangular);
  772.   CSet (a[13],  1.0, -1.0, rectangular);
  773.   CSet (a[14],   5.,   0., rectangular);
  774.   CSet (a[15],   5.,   3., rectangular);
  775.   CSet (a[16],   0.,   3., rectangular);
  776.   CSet (a[17],  -5.,   3., rectangular);
  777.   CSet (a[18],  -5.,   0., rectangular);
  778.   CSet (a[19],  -5.,  -3., rectangular);
  779.   CSet (a[20],   0.,  -3., rectangular);
  780.   CSet (a[21],  -5.,  -3., rectangular);
  781.   CSet (a[22], -20.,  20., rectangular);
  782.  
  783.   WRITELN ('Complex number definition/conversion/output:  CSet/CConvert/CStr');
  784.   WRITELN;
  785.   WRITELN ('   z rectangular':25,'z polar':28);
  786.   WRITELN ('     ---------------------------   ',
  787.     '-----------------------------');
  788.   FOR k := 1 TO 21 DO
  789.     WRITELN (k:3,'  ',CStr(a[k],12,8,rectangular),'  ',
  790.                      CStr(a[k],12,8,polar));
  791.   WRITELN;
  792.   WRITELN;
  793.  
  794.   WRITELN ('Complex arithmetic:  CAdd, CSub, CMult, CDiv');
  795.   WRITELN;
  796.  
  797.   CSet (z1,  1, 1, rectangular);
  798.   WRITELN ('Let z1 = ':12,CStr(z1,8,3,rectangular):20,' or ',
  799.                       CStr(z1,8,3,polar));
  800.   CSet (z2, SQRT(3), -1, rectangular);
  801.   WRITELN ('z2 = ':12,CStr(z2,8,3,rectangular):20,' or ',
  802.                       CStr(z2,8,3,polar));
  803.   WRITELN;
  804.  
  805.   CAdd  (z,z1,z2);
  806.   WRITELN ('z1 + z2 = ':12,CStr(z,8,3,rectangular):20,' or ',
  807.                            CStr(z,8,3,polar));
  808.  
  809.   CSub  (z,z1,z2);
  810.   WRITELN ('z1 - z2 = ':12,CStr(z,8,3,rectangular):20,' or ',
  811.                            CStr(z,8,3,polar));
  812.  
  813.   CMult (z,z1,z2);
  814.   WRITELN ('z1 * z2 = ':12,CStr(z,8,3,rectangular):20,' or ',
  815.                            CStr(z,8,3,polar));
  816.  
  817.   CDiv  (z,z1,z2);
  818.   WRITELN ('z1 / z2 = ':12,CStr(z,8,3,rectangular):20,' or ',
  819.                            CStr(z,8,3,polar));
  820.   WRITELN;
  821.   WRITELN;
  822.  
  823.   WRITELN ('Complex natural logarithm:  CLn = LN(z)');
  824.   WRITELN;
  825.   WRITELN ('  Notes:  1.  LN(z) is multivalued.');
  826.   WRITELN (' ':9,' 2.  Any multiple of 2*PI*i could be added to/',
  827.     'subtracted from LN(z).');
  828.   WRITELN (' ':9,' 3.  LN(1)=0; LN(-1)=PI*i; LN(+/-i)=+/-0.5*PI*i.');
  829.   WRITELN;
  830.   WRITELN ('LN(z)':35);
  831.   WRITELN ('z':11,'rectangular':27,'EXP( LN(z) ) = z':32);
  832.   WRITELN ('     ------------  ---------------------------  ',
  833.     '---------------------------');
  834.   FOR k := 1 TO 22 DO BEGIN
  835.     WRITE (k:3,' ',CStr(a[k],5,1,rectangular),'  ');
  836.     IF   CAbs(a[k]) = 0.0
  837.     THEN WRITELN ('undefined':18)
  838.     ELSE BEGIN
  839.       CLn (z,a[k]);
  840.       CExp (z1,z);
  841.       WRITELN (CStr(z,12,9,rectangular),'  ',CStr(z1,12,9,rectangular))
  842.     END
  843.   END;
  844.   WRITELN;
  845.   WRITELN;
  846.  
  847.   WRITELN ('Complex exponential:  CExp = EXP(z)');
  848.   WRITELN;
  849.   WRITELN ('EXP(z)':35);
  850.   WRITELN ('z':11,'rectangular':27,'LN( EXP(z) ) = z':32);
  851.   WRITELN ('     ------------  ---------------------------  ',
  852.     '---------------------------');
  853.   FOR k := 1 TO 22 DO BEGIN
  854.     WRITE (k:3,' ',CStr(a[k],5,1,rectangular),'  ');
  855.     CExp (z,a[k]);
  856.     CLn (z1,z);
  857.     IF   CAbs(z) > 10.0
  858.     THEN m := 7
  859.     ELSE m := 9;
  860.     WRITELN (CStr(z,12,m,rectangular),'  ',CStr(z1,12,m,rectangular))
  861.   END;
  862.   WRITELN;
  863.   WRITELN;
  864.  
  865.   WRITELN ('Complex power:  CPwr = z1^z2');
  866.   WRITELN;
  867.   WRITELN ('z^(-1+i)':36,'z^(-1+i)':29);
  868.   WRITELN ('z':11,'rectangular':27,'polar':26);
  869.   WRITELN ('     ------------  ---------------------------  ',
  870.     '-----------------------------');
  871.   CSet (z1, -1,1, rectangular);
  872.   FOR k := 1 TO 21 DO BEGIN
  873.     WRITE (k:3,' ',CStr(a[k],5,1,rectangular),'  ');
  874.     IF   CAbs(a[k]) = 0.0
  875.     THEN WRITELN ('undefined':18)
  876.     ELSE BEGIN
  877.       CPwr (z,a[k],z1);
  878.       WRITELN (CStr(z,12,9,rectangular),' ',CStr(z,12,9,polar))
  879.     END
  880.   END;
  881.   WRITELN;
  882.   WRITELN;
  883.  
  884.   WRITELN ('Complex cosine:  CCos = COS(z)');
  885.   WRITELN;
  886.   WRITELN ('COS(z)':35,'COS(z)':29);
  887.   WRITELN ('z':11,'rectangular':27,'polar':26);
  888.   WRITELN ('     ------------  ---------------------------  ',
  889.     '-----------------------------');
  890.   FOR k := 1 TO 21 DO BEGIN
  891.     WRITE (k:3,' ',CStr(a[k],5,1,rectangular),'  ');
  892.     CCos (z,a[k]);
  893.     CIntPwr (csave[k], z,2);  {save COS^2}
  894.     IF   CAbs(z) > 10.0
  895.     THEN m := 7
  896.     ELSE m := 9;
  897.     WRITELN (CStr(z,12,m,rectangular),' ',CStr(z,12,m,polar))
  898.   END;
  899.   WRITELN;
  900.   WRITELN;
  901.  
  902.   WRITELN ('Complex sine:  CSin = SIN(z)');
  903.   WRITELN;
  904.   WRITELN ('SIN(z)':35);
  905.   WRITELN ('z':11,'rectangular':27,'SIN^2(z)+COS^2(z)=1':32);
  906.   WRITELN ('     ------------  ---------------------------  ',
  907.     '---------------------------');
  908.   FOR k := 1 TO 21 DO BEGIN
  909.     WRITE (k:3,' ',CStr(a[k],5,1,rectangular),'  ');
  910.     CSin (z,a[k]);
  911.     CIntPwr (z1, z,2);      {SIN^2}
  912.     CAdd (z1, z1,csave[k]); {SIN^2 + COS^2}
  913.     IF   CAbs(z) > 10.0
  914.     THEN m := 7
  915.     ELSE m := 9;
  916.     WRITELN (CStr(z,12,m,rectangular),'  ',CStr(z1,12,9,rectangular))
  917.   END;
  918.   WRITELN;
  919.   WRITELN;
  920.  
  921.   WRITELN ('Complex tangent:  CTan = TAN(z)');
  922.   WRITELN;
  923.   WRITELN ('TAN(z)':35,'TAN(z)':29);
  924.   WRITELN ('z':11,'rectangular':27,'polar':26);
  925.   WRITELN ('     ------------  ---------------------------  ',
  926.     '-----------------------------');
  927.   FOR k := 1 TO 21 DO BEGIN
  928.     WRITE (k:3,' ',CStr(a[k],5,1,rectangular),'  ');
  929.     CTan (z,a[k]);
  930.     IF   CAbs(z) > 10.0
  931.     THEN m := 7
  932.     ELSE m := 9;
  933.     WRITELN (CStr(z,12,m,rectangular),' ',CStr(z,12,m,polar))
  934.   END;
  935.   WRITELN;
  936.   WRITELN;
  937.  
  938.   WRITELN ('Complex hyperbolic cosine:  CCosh = COSH(z)');
  939.   WRITELN;
  940.   WRITELN ('COSH(z)':36,'COSH(z)':29);
  941.   WRITELN ('z':11,'rectangular':27,'polar':26);
  942.   WRITELN ('     ------------  ---------------------------  ',
  943.     '-----------------------------');
  944.   FOR k := 1 TO 21 DO BEGIN
  945.     WRITE (k:3,' ',CStr(a[k],5,1,rectangular),'  ');
  946.     CCosh (z,a[k]);
  947.     CIntPwr (csave[k], z,2);  {save COSH^2}
  948.     IF   CAbs(z) > 10.0
  949.     THEN m := 7
  950.     ELSE m := 9;
  951.     WRITELN (CStr(z,12,m,rectangular),' ',CStr(z,12,m,polar))
  952.   END;
  953.   WRITELN;
  954.   WRITELN;
  955.  
  956.   WRITELN ('Complex hyperbolic sine:  CSinh = SINH(z)');
  957.   WRITELN;
  958.   WRITELN ('SINH(z)':36);
  959.   WRITELN ('z':11,'rectangular':27,'COSH^2(z)-SINH^2(z)=1':34);
  960.   WRITELN ('     ------------  ---------------------------  ',
  961.     '---------------------------');
  962.   FOR k := 1 TO 21 DO BEGIN
  963.     WRITE (k:3,' ',CStr(a[k],5,1,rectangular),'  ');
  964.     CSinh (z,a[k]);
  965.     CIntPwr (z1, z,2);      {SINH^2}
  966.     CSub (z1, csave[k],z1); {COSH^2 - SINH^2}
  967.     IF   CAbs(z) > 10.0
  968.     THEN m := 7
  969.     ELSE m := 9;
  970.     WRITELN (CStr(z,12,m,rectangular),'  ',CStr(z1,12,9,rectangular))
  971.   END;
  972.   WRITELN;
  973.   WRITELN;
  974.  
  975.   WRITELN ('Complex hyperbolic tangent:  CTanh = TANH(z)');
  976.   WRITELN;
  977.   WRITELN ('TANH(z)':36,'TANH(z)':29);
  978.   WRITELN ('z':11,'rectangular':27,'polar':26);
  979.   WRITELN ('     ------------  ---------------------------  ',
  980.     '-----------------------------');
  981.   FOR k := 1 TO 21 DO BEGIN
  982.     WRITE (k:3,' ',CStr(a[k],5,1,rectangular),'  ');
  983.     CTanh (z,a[k]);
  984.     IF   CAbs(z) > 10.0
  985.     THEN m := 4
  986.     ELSE m := 9;
  987.     WRITELN (CStr(z,12,m,rectangular),' ',CStr(z,12,m,polar))
  988.   END;
  989.   WRITELN;
  990.   WRITELN;
  991.  
  992.   WRITELN ('Absolute value of complex number:  CAbs = ABS(z)');
  993.   WRITELN;
  994.   WRITELN ('z':11,'ABS(z)':17);
  995.   WRITELN ('     ------------  ------------');
  996.   FOR k := 1 TO 21 DO BEGIN
  997.     WRITELN (k:3,' ',CStr(a[k],5,1,rectangular),'  ',CAbs(a[k]):12:9)
  998.   END;
  999.   WRITELN;
  1000.  
  1001.   WRITELN ('Complex integer power:  CIntPwr = z^n  ',
  1002.     '(using DeMoivre''s Theorem)');
  1003.   WRITELN;
  1004.   WRITELN ('z^3':34,'z^3':29);
  1005.   WRITELN ('z':11,'rectangular':27,'polar':26);
  1006.   WRITELN ('     ------------  ---------------------------  ',
  1007.     '-----------------------------');
  1008.   FOR k := 1 TO 21 DO BEGIN
  1009.     WRITE (k:3,' ',CStr(a[k],5,1,rectangular),'  ');
  1010.     IF   CAbs(a[k]) = 0.0
  1011.     THEN WRITELN ('undefined':18)
  1012.     ELSE BEGIN
  1013.       CIntPwr (z,a[k],3);
  1014.       IF   CAbs(z) > 10.0
  1015.       THEN m := 7
  1016.       ELSE m := 9;
  1017.       WRITELN (CStr(z,12,m,rectangular),' ',CStr(z,12,m,polar))
  1018.     END
  1019.   END;
  1020.   WRITELN;
  1021.   WRITELN;
  1022.  
  1023.   WRITELN ('Complex conjugate:  CConjugate = z*');
  1024.   WRITELN;
  1025.   WRITELN ('z*':35,'z*':29);
  1026.   WRITELN ('z':11,'rectangular':28,'polar':26);
  1027.   WRITELN ('     ------------  ---------------------------  ',
  1028.     '-----------------------------');
  1029.   FOR k := 1 TO 21 DO BEGIN
  1030.     WRITE (k:3,' ',CStr(a[k],5,1,rectangular),'  ');
  1031.     CConjugate (z,a[k]);
  1032.     WRITELN (CStr(z,12,8,rectangular),' ',CStr(z,12,8,polar))
  1033.   END;
  1034.   WRITELN;
  1035.   WRITELN;
  1036.  
  1037.   WRITELN ('Complex square root:  CSqrt = SQRT(z)');
  1038.   WRITELN;
  1039.   WRITELN ('SQRT(z)':36,'SQRT(z)':28);
  1040.   WRITELN ('z':11,'root 1':25,'root 2':28);
  1041.   WRITELN ('     ------------  ---------------------------  ',
  1042.     '---------------------------');
  1043.   FOR k := 1 TO 21 DO BEGIN
  1044.     WRITE (k:3,' ',CStr(a[k],5,1,rectangular),'  ');
  1045.     CSqrt (z,a[k]);       {same as CRoot (z,a[k],0,2)}
  1046.     CRoot (z1,a[k],1,2);
  1047.     WRITELN (CStr(z,12,9,rectangular),'  ',CStr(z1,12,9,rectangular))
  1048.   END;
  1049.   WRITELN;
  1050.   WRITELN;
  1051.  
  1052.   WRITELN ('The three cube roots of -1+i:  (-1+i)^(1/3)');
  1053.   WRITELN ('(See Schaum''s Outline Series "Complex Variables", 1964, ',
  1054.     'p. 18, problem 29.)');
  1055.   WRITELN;
  1056.   WRITELN ('z^(1/3)':35,'z^(1/3)':29);
  1057.   WRITELN ('z':11,'rectangular':27,'polar':26);
  1058.   WRITELN ('     ------------  ---------------------------  ',
  1059.     '-----------------------------');
  1060.   CSet (z1, -1,1, rectangular);
  1061.   FOR k := 0 TO 2 DO BEGIN
  1062.     WRITE (k:3,' ',CStr(z1,5,1,rectangular),'  ');
  1063.     CRoot (z,z1,k,3);
  1064.     WRITELN (CStr(z,12,9,rectangular),' ',CStr(z,12,9,polar))
  1065.   END;
  1066.   WRITELN;
  1067.   WRITELN;
  1068.  
  1069.   WRITELN ('Complex Bessel function:  CI0 = I0(z)');
  1070.   WRITELN;
  1071.   WRITELN ('I0(z)':36,'I0(z)':29);
  1072.   WRITELN ('z':11,'rectangular':27,'polar':26);
  1073.   WRITELN ('     ------------  ---------------------------  ',
  1074.     '-----------------------------');
  1075.   FOR k := 1 TO 21 DO BEGIN
  1076.     WRITE (k:3,' ',CStr(a[k],5,1,rectangular),'  ');
  1077.     CI0 (z,a[k]);
  1078.     IF   CAbs(z) > 10.0
  1079.     THEN m := 7
  1080.     ELSE m := 9;
  1081.     WRITELN (CStr(z,12,m,rectangular),' ',CStr(z,12,m,polar))
  1082.   END;
  1083.   WRITELN;
  1084.   WRITELN;
  1085.  
  1086.   WRITELN ('Complex Bessel function:  CJ0 = J0(z)');
  1087.   WRITELN;
  1088.   WRITELN ('J0(z)':36,'J0(z)':29);
  1089.   WRITELN ('z':11,'rectangular':27,'polar':26);
  1090.   WRITELN ('     ------------  ---------------------------  ',
  1091.     '-----------------------------');
  1092.   FOR k := 1 TO 21 DO BEGIN
  1093.     WRITE (k:3,' ',CStr(a[k],5,1,rectangular),'  ');
  1094.     CJ0 (z,a[k]);
  1095.     IF   CAbs(z) > 10.0
  1096.     THEN m := 7
  1097.     ELSE m := 9;
  1098.     WRITELN (CStr(z,12,m,rectangular),' ',CStr(z,12,m,polar))
  1099.   END;
  1100.   WRITELN;
  1101.   WRITELN;
  1102.  
  1103.   WRITELN ('Removing "Fuzz" from real numbers for zero test:');
  1104.   WRITELN;  {Note:  CStr calls CConvert that calls CDefuzz}
  1105.   CSet (z, -3.21E-14,7.65E-14, rectangular);
  1106.   WRITELN ('  Before:  ',z.x:18:15,' +',z.y:18:15,'i');
  1107.   CDeFuzz (z);
  1108.   WRITELN ('   After:  ',CStr(z,18,15,rectangular));
  1109.   WRITELN;
  1110.   CSet (z, -3.21E-14,PI, polar);
  1111.   WRITELN ('  Before:  ',z.r:18:15,'*CIS(',z.theta:18:15,')');
  1112.   CDeFuzz (z);
  1113.   WRITELN ('   After:  ',CStr(z,18,15,polar));
  1114.   WRITELN;
  1115.   WRITELN;
  1116.  
  1117.   WRITELN ('Miscellaneous:  FixAngle -- keep angle in interval (-PI..PI)');
  1118.   WRITELN;
  1119.  
  1120.   WRITELN ('     radians FixAngle');
  1121.   WRITELN ('    -------- --------');
  1122.   FOR n := -4 TO 8 DO BEGIN
  1123.     x := n*PI/2.0;
  1124.     y := FixAngle(x);
  1125.     WRITELN (n:3,' ',x:8:5,' ',y:8:5)
  1126.   END;
  1127.   WRITELN;
  1128.   WRITELN;
  1129.  
  1130.   WRITELN ('Real power function:  Pwr = x^y');
  1131.   WRITELN;
  1132.   WRITELN ('        x        y         x^y');
  1133.   WRITELN ('    -------- -------- ------------');
  1134.   WRITELN (' ':4,2.1:8:5,' ',-2.5:8:5,Pwr(2.1,-2.5):12:9);
  1135.   WRITELN (' ':4,2.1:8:5,' ', 2.5:8:5,Pwr(2.1, 2.5):12:9);
  1136.   WRITELN (' ':4,1.4:8:5,' ', 8.9:8:5,Pwr(1.2, 8.9):12:9);
  1137.   WRITELN (' ':4,0.0:8:5,' ', 2.0:8:5,Pwr(0.0, 2.0):12:9);
  1138.   WRITELN (' ':4,4.2:8:5,' ', 0.0:8:5,Pwr(4.2, 0.0):12:9);
  1139.   WRITELN;
  1140.  
  1141. END {cdemo}.
  1142.